Lithium data

Quantities that use the Mathematica “Quantity” functionality have the first letter in 𝓈𝒸𝓇𝒾𝓅𝓉.

celsiusToKelvin=Quantity[0.,"DegreesCelsius"]//UnitConvert//QuantityMagnitude; 
𝓀b=UnitConvert[Quantity["BoltzmannConstant"],"Joules"/"Kelvins"];
kb=𝓀b//UnitConvert//QuantityMagnitude;

The atomic weight of natural lithium varies from source to source, such that IUPAC [1] does not provide one number for a ‘standard atomic weight’ as it does for most elements; rather it gives the range [6.938, 6.997]. It does provide a ‘conventional atomic weight’ of Li of 6.94, “For users needing an atomic-weight value for an unspecified sample with disregard to the uncertainty, such as for trade and commerce”. In further studies we will use 6.94, but here the values 6.941 and 6.9 are retained for consistency.

[1] Meija, Juris, Tyler B. Coplen, Michael Berglund, Willi A. Brand, Paul De Bièvre, Manfred Gröning, Norman E. Holden, et al. “Atomic Weights of the Elements 2013 (IUPAC Technical Report).” Pure and Applied Chemistry 88, no. 3 (January 1, 2016). https://doi.org/10.1515/pac-2015-0305.

𝓂Li=6.941 Quantity["AtomicMassUnit"];
mLi=𝓂Li//UnitConvert//QuantityMagnitude; (* in kg *)

This single value for the latent heat of lithium, 147 kJ/mol, was curated by Mathematica. The literature, such as from Golubchikov, below, gives latent heat values as a function of temperature. This value is consistent with Golubchikov’s values to within 5% from the melting point of lithium up to 1000K.

ℓLi =((Quantity[147 (10^3),"Joules"/"Moles"])/(Quantity[6.9 (10^(-3)),"Kilograms"/"Moles"]));
lLi=ℓLi//QuantityMagnitude;

Vapor pressure of lithium, in Pascals, as a function of temperature. This value, from [3], is a truncated version of the best fit given in [2]. Future work will use 
[2]. 

[2] Browning, P, and P. E. Potter. “Section 6.2: Assessment of the Experimentally Determined Vapour Pressures of the Liquid Alkali Metals.” In Handbook of Thermodynamic and Transport Properties of Alkali Metals, edited by R.W. Ohse, 349–58. Oxford: Blackwell Scientific Publications, 1985.

[3] Section 8.1.2 of http://www.fusion.ucla.edu/APEX/interim_report/chapter8full2.pdf  Chapter 8: Data base for liquid breeders and coolants. Contributors: Kai Sze, Ralph Moir, Steve Zinkle.

pLi[TK_]:=Exp[26.89 - 18880/TK-0.4942 Log[TK]];

Here, the density of lithium vapor is calculated according to the ideal gas law, assuming that Li is entirely a gas of monomers.

𝓅Li[TK_]:=Quantity[pLi[TK],"Pascals"];
𝓅Li[T𝕂_Quantity]:=Quantity[pLi[QuantityMagnitude[T𝕂]],"Pascals"];

𝓃eqLi[TC_]:=UnitConvert[𝓅Li[TC+celsiusToKelvin] /(𝓀b Quantity[(TC+celsiusToKelvin),"Kelvins"]),"Meters"-3];
𝓃eqLi[T𝕂_Quantity]:=UnitConvert[𝓅Li[T𝕂] /(𝓀b T𝕂)];

neqLi[TC_]:=𝓃eqLi[TC]//UnitConvert//QuantityMagnitude;

The Hertz-Knudsen one-way flux through a surface area.

ΓLi[T𝕂_Quantity]:=𝓃eqLi[T𝕂] (Sqrt[𝓀b T𝕂/(2π 𝓂Li)])//UnitConvert;
ΓLi[TK_]:=ΓLi[Quantity[TK,"Kelvins"]]

The flux of latent heat through a surface area.

(* Latent heat flux through a surface at some density and temperature *)
ΓℓLi[𝓃_,T𝕂_]:=ℓLi 𝓂Li 𝓃 (Sqrt[𝓀b T𝕂/(2π 𝓂Li)])//UnitConvert

Alternate Li data

Vapor pressure of lithium.

Vapor pressure of lithium, as reported in [4].

[4] Golubchikov, L. G., V. A. Evtikhin, I. E. Lyublinski, V. I. Pistunovich, I. N. Potapov, and A. N. Chumanov. "Development of a Liquid-Metal Fusion Reactor Divertor with a Capillary-Pore System." Journal of Nuclear Materials 233 (1996): 667–672.

pLiGolub[TK_]:=10^(12.4037-8283.1/TK-0.7081 Log10[TK])

Notes: Golubchikov’s table also gives values for 200, 600, and 1200°C, = {1.4 (10^(-6)), 14.8, and 42650 Pa}. They don’t seem to match with the formula.

Latent heat of evaporation, as a function of temperature.

From [4].

ℓaLiTGolub[TK_]:=2.4525 (10^7)-2967.14(TK+273)-0.1762(((TK+273))^2);